mirror of
https://xff.cz/git/u-boot/
synced 2025-10-31 10:26:10 +01:00
83d290c56f
When U-Boot started using SPDX tags we were among the early adopters and there weren't a lot of other examples to borrow from. So we picked the area of the file that usually had a full license text and replaced it with an appropriate SPDX-License-Identifier: entry. Since then, the Linux Kernel has adopted SPDX tags and they place it as the very first line in a file (except where shebangs are used, then it's second line) and with slightly different comment styles than us. In part due to community overlap, in part due to better tag visibility and in part for other minor reasons, switch over to that style. This commit changes all instances where we have a single declared license in the tag as both the before and after are identical in tag contents. There's also a few places where I found we did not have a tag and have introduced one. Signed-off-by: Tom Rini <trini@konsulko.com>
67 lines
1.2 KiB
ArmAsm
67 lines
1.2 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0+ */
|
|
/*
|
|
* Copyright (C) 2016 Vladimir Zapolskiy <vz@mleia.com>
|
|
* Copyright (C) 2007, 2010 Nobuhiro Iwamatsu <iwamatsu@nigauri.org>
|
|
*/
|
|
|
|
#include <asm-offsets.h>
|
|
#include <config.h>
|
|
|
|
.text
|
|
.align 2
|
|
|
|
.global _start
|
|
_start:
|
|
#ifdef CONFIG_CPU_SH2
|
|
.long 0x00000010 /* Ppower ON reset PC*/
|
|
.long 0x00000000
|
|
.long 0x00000010 /* Manual reset PC */
|
|
.long 0x00000000
|
|
#endif
|
|
mov.l ._lowlevel_init, r0
|
|
100: bsrf r0
|
|
nop
|
|
|
|
bsr 1f
|
|
nop
|
|
1: sts pr, r5
|
|
mov.l ._reloc_dst, r4
|
|
add #(_start-1b), r5
|
|
mov.l ._reloc_dst_end, r6
|
|
|
|
2: mov.l @r5+, r1
|
|
mov.l r1, @r4
|
|
add #4, r4
|
|
cmp/hs r6, r4
|
|
bf 2b
|
|
|
|
mov.l ._bss_start, r4
|
|
mov.l ._bss_end, r5
|
|
mov #0, r1
|
|
|
|
3: mov.l r1, @r4 /* bss clear */
|
|
add #4, r4
|
|
cmp/hs r5, r4
|
|
bf 3b
|
|
|
|
mov.l ._gd_init, r13 /* global data */
|
|
mov.l ._stack_init, r15 /* stack */
|
|
|
|
mov.l ._sh_generic_init, r0
|
|
jsr @r0
|
|
mov #0, r4
|
|
|
|
loop:
|
|
bra loop
|
|
|
|
.align 2
|
|
|
|
._lowlevel_init: .long (lowlevel_init - (100b + 4))
|
|
._reloc_dst: .long _start
|
|
._reloc_dst_end: .long reloc_dst_end
|
|
._bss_start: .long bss_start
|
|
._bss_end: .long bss_end
|
|
._gd_init: .long (_start - GENERATED_GBL_DATA_SIZE)
|
|
._stack_init: .long (_start - GENERATED_GBL_DATA_SIZE - CONFIG_SYS_MALLOC_LEN - 16)
|
|
._sh_generic_init: .long board_init_f
|