phoc/phosh: initial add needed recipes

recipes-extended/callaudiod/callaudiod_git.bb

@@ -0,0 +1,20 @@
+SUMMARY = "callaudiod is a daemon for dealing with audio routing during phone calls."
+HOMEPAGE = "https://gitlab.com/mobian1/callaudiod"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+DEPENDS = "glib-2.0 alsa-lib pulseaudio"
+RDEPENDS:${PN} += "pulseaudio-server"
+
+inherit meson pkgconfig
+
+SRC_URI = " \
+    git://gitlab.com/mobian1/callaudiod.git;protocol=https;branch=master \
+"
+
+S = "${WORKDIR}/git"
+PV = "0.1.3"
+SRCREV = "4cb8bd9d228d13ea67e79f4c37c674f412b32d20"
+
+FILES:${PN} += "${datadir}"
+

recipes-extended/feedbackd/feedbackd_git.bb

@@ -0,0 +1,30 @@
+SUMMARY = "A daemon to provide haptic, led and audio feedback triggered by application events."
+HOMEPAGE = "https://source.puri.sm/Librem5/feedbackd"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
+
+DEPENDS = " \
+    gsound \
+    libgudev \
+    glib-2.0 \
+    json-glib \
+"
+
+GIR_MESON_OPTION = ""
+
+inherit meson pkgconfig features_check gobject-introspection vala
+
+SRC_URI = " \
+    git://source.puri.sm/Librem5/feedbackd.git;protocol=https;branch=master \
+"
+
+S = "${WORKDIR}/git"
+PV = "0.0.0+git20220208"
+SRCREV = "74b178a363f1e0e4b84309f2a1b1c1c41bf97248"
+
+EXTRA_OEMESON += "-Dtests=false"
+
+FILES:${PN} += "${datadir}"
+

recipes-wlroots/phoc/phoc_git.bb

@@ -0,0 +1,55 @@
+
+SUMMARY = "wlroots based Phone compositor as used on the Librem5."
+HOMEPAGE = "https://gitlab.gnome.org/World/Phosh/phoc"
+SECTION = "graphics"
+LICENSE = "GPL-3.0"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+DEPENDS += " \
+	glib-2.0 \
+	gnome-desktop \
+	libinput \
+	libxkbcommon \
+	pixman \
+	seatd \
+	systemd \
+	wayland \
+	wayland-native \
+	wayland-protocols \
+"
+#needed to build wlroots as a subproject
+DEPENDS += " \
+	ffmpeg \
+	git-native \
+	libdrm \
+	libcap \
+	virtual/libgbm \
+	virtual/libgles2 \
+	libpng \
+	systemd \
+"
+
+RDEPENDS:${PN} = "mutter"
+
+SRC_URI = " \
+	gitsm://gitlab.gnome.org/World/Phosh/phoc.git;protocol=https;branch=master \
+"
+
+SRCREV = "eb62bea7cfb3ca0a4fe417811a868e3ac95b81c5"
+PV = "0.12.0"
+S = "${WORKDIR}/git"
+
+inherit features_check gsettings meson pkgconfig
+
+EXTRA_OEMESON += "-Dembed-wlroots=enabled"
+
+PACKAGECONFIG[x11] = ",,libxcb xcb-util-renderutil"
+PACKAGECONFIG[xwayland] = "-Dxwayland=enabled,-Dxwayland=disabled,xwayland xcb-util-wm"
+
+PACKAGECONFIG ?= ""
+
+FILES:${PN} += "${datadir}"
+

recipes-wlroots/phosh/phosh_0.15.0.bb

@@ -0,0 +1,50 @@
+SUMMARY = "a pure wayland shell for mobile devices like Purism's Librem 5."
+HOMEPAGE = "https://source.puri.sm/Librem5/feedbackd"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+REQUIRED_DISTRO_FEATURES = "wayland polkit systemd pam pulseaudio"
+
+DEPENDS = " \
+    callaudiod \
+    feedbackd \
+    fribidi \
+    gcr \
+    git-native \
+    glib-2.0 \
+    gnome-desktop \
+    gtk+3 \
+    libgudev \
+    libhandy \
+    libpam \
+    libsecret \
+    networkmanager \
+    polkit \
+    pulseaudio \
+    systemd \
+    upower \
+    wayland \
+    wayland-native \
+    wayland-protocols \
+"
+
+RDEPENDS:${PN} = " \
+    gnome-control-center \
+    gnome-session \
+    gnome-settings-daemon \
+    gsettings-desktop-schemas \
+    phoc \
+"
+
+inherit features_check gsettings meson pkgconfig
+
+SRC_URI = " \
+    gitsm://gitlab.gnome.org/World/Phosh/phosh.git;protocol=https;nobranch=1 \
+"
+
+S = "${WORKDIR}/git"
+PV = "0.15.0"
+SRCREV = "a964be122953d4cbcf63b75793c60f231ec35d71"
+
+FILES:${PN} += "${datadir}"
+