labwc: add recipe

labwc is a wlroots based wayland stacking manager that aims to provide the
look and feel of openbox.

recipes-wlroots/labwc/labwc-tweaks_git.bb

@@ -0,0 +1,24 @@
+
+SUMMARY = "This is a [WIP] configuration gui app for labwc without any real plan or Acceptance Criteria"
+HOMEPAGE = "https://github.com/labwc/labwc-tweaks"
+SECTION = "graphics"
+LICENSE = "GPL-2.0-only"
+
+LIC_FILES_CHKSUM = "file://gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+DEPENDS += " \
+	libxml2 \
+	glib-2.0 \
+	gtk+3 \
+"
+
+SRC_URI = "git://github.com/labwc/labwc-tweaks.git;protocol=https;branch=master"
+
+SRCREV = "253667cb776cd74d9f39067721b1bf5f729c7b45"
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig features_check
+
+FILES:${PN} += "${datadir}"

recipes-wlroots/labwc/labwc_git.bb

@@ -0,0 +1,48 @@
+
+SUMMARY = "Labwc stands for Lab Wayland Compositor"
+HOMEPAGE = "https://github.com/labwc/labwc"
+SECTION = "graphics"
+LICENSE = "GPL-2.0-only"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+DEPENDS += " \
+	libxml2 \
+	glib-2.0 \
+	cairo \
+	pango \
+	wayland \
+	wayland-native \
+	wayland-protocols \
+	libdrm \
+	libxkbcommon \
+	libinput \
+	wlroots-0.16 \
+"
+
+RRECOMMENDS:${PN} ?= " \
+	foot \
+	grim \
+	slurp \
+	wl-clipboard \
+	labwc-tweaks \
+	swaybg \
+"
+
+SRC_URI = "git://github.com/labwc/labwc.git;protocol=https;branch=master"
+
+SRCREV = "a3fff9f87b0dd05f2e2c8036c4c231f8ec40ed98"
+PV = "0.6.1"
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig features_check gettext
+
+PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'xwayland', d)}"
+
+PACKAGECONFIG[man-pages] = "-Dman-pages=enabled,-Dman-pages=disabled,scdoc-native"
+PACKAGECONFIG[xwayland] = "-Dxwayland=enabled,-Dxwayland=disabled,libxcb xcb-util-wm xcb-util-renderutil xwayland,xwayland"
+
+FILES:${PN} += "${datadir}"
+