hyprland: add recipe for 0.38

update to 0.38.1

recipes-wlroots/hyprland/hyprland-0.38_0.38.1.bb

@@ -0,0 +1,57 @@
+SUMMARY = "A Wayland WM"
+HOMEPAGE = "https://hyprland.org/"
+SECTION = "graphics"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e5285450935e9c47f839569c8cbd4e29"
+
+REQUIRED_DISTRO_FEATURES = "wayland opengl"
+
+DEPENDS += " \
+	cairo \
+	hyprcursor \
+	hyprlang \
+	jq-native \
+	libdrm \
+	libinput \
+	libxkbcommon \
+	pango \
+	pixman \
+	tomlplusplus \
+	udis86 \
+	virtual/egl \
+	wayland \
+	wayland-native \
+	wlroots \
+"
+
+RRECOMMENDS:${PN} ?= " \
+	foot \
+	jq \
+	grim \
+	slurp \
+	wl-clipboard \
+	hyprland-contrib \
+"
+
+SRC_URI = " \
+	gitsm://github.com/hyprwm/Hyprland.git;protocol=https;branch=v0.38.1-b \
+	file://meson-build.patch \
+"
+
+SRCREV = "360ede79d124ffdeebbe8401f1ac4bc0dbec2c91"
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig features_check
+
+PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd xwayland', d)}"
+
+PACKAGECONFIG[systemd] = "-Dsystemd=enabled,-Dsystemd=disabled"
+PACKAGECONFIG[xwayland] = "-Dxwayland=enabled,-Dxwayland=disabled,libxcb xcb-util-wm xcb-util-renderutil xwayland,xwayland"
+PACKAGECONFIG[legacy_renderer] = "-Dlegacy_renderer=enabled,-Dlegacy_renderer=disabled"
+
+do_configure:prepend() {
+	cd ${S} && scripts/generateVersion.sh
+}
+
+FILES:${PN} += "${datadir}"