diff --git a/conf/layer.conf b/conf/layer.conf
index 5cd2d0e..612f2f3 100644
--- a/conf/layer.conf
+++ b/conf/layer.conf
@@ -14,3 +14,8 @@ LAYERDEPENDS_wayland = " \
 	core \
 	openembedded-layer \
 "
+
+BBFILES_DYNAMIC += " \
+    qt6-layer:${LAYERDIR}/dynamic-layers/meta-qt6/*/*/*.bb \
+    qt6-layer:${LAYERDIR}/dynamic-layers/meta-qt6/*/*/*.bbappend \
+"
diff --git a/dynamic-layers/meta-qt6/recipes-qt/adwaita-qt/adwaita-qt_1.4.2.bb b/dynamic-layers/meta-qt6/recipes-qt/adwaita-qt/adwaita-qt_1.4.2.bb
new file mode 100644
index 0000000..a5ad231
--- /dev/null
+++ b/dynamic-layers/meta-qt6/recipes-qt/adwaita-qt/adwaita-qt_1.4.2.bb
@@ -0,0 +1,17 @@
+SUMMARY = "A native style to bend Qt5/Qt6 applications to look like they belong into GNOME Shell.."
+HOMEPAGE = "https://github.com/FedoraQt/adwaita-qt"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5c213a7de3f013310bd272cdb6eb7a24"
+
+DEPENDS = "qtbase"
+
+inherit qt6-cmake
+
+EXTRA_OECMAKE += "-DUSE_QT6=ON"
+
+SRC_URI = "git://github.com/FedoraQt/adwaita-qt.git;protocol=https;nobranch=1"
+
+S = "${WORKDIR}/git"
+SRCREV = "07859143fd733cfefae687f6967795c7f50d4ca8"
+
+FILES:${PN} += "${libdir}/plugins/styles/adwaita.so"
diff --git a/dynamic-layers/meta-qt6/recipes-qt/hyprland-share-picker/hyprland-share-picker.bb b/dynamic-layers/meta-qt6/recipes-qt/hyprland-share-picker/hyprland-share-picker.bb
new file mode 100644
index 0000000..67c56b2
--- /dev/null
+++ b/dynamic-layers/meta-qt6/recipes-qt/hyprland-share-picker/hyprland-share-picker.bb
@@ -0,0 +1,19 @@
+SUMMARY = "Share picker for hyprlands screenshot/screencast xdg-desktop-portal backend"
+HOMEPAGE = "https://github.com/hyprwm/xdg-desktop-portal-hyprland"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://../LICENSE;md5=e316e9609dd7672b87ff25b46b2cf3e1"
+
+# Note: meta-qt6 is needed
+DEPENDS = "qtbase"
+RDEPENDS:${PN} = "qtwayland"
+RRECOMMENDS:${PN} = "adwaita-qt"
+
+inherit qt6-cmake features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl wayland"
+
+SRC_URI = "git://github.com/hyprwm/xdg-desktop-portal-hyprland.git;protocol=https;nobranch=1"
+
+S = "${WORKDIR}/git/hyprland-share-picker"
+SRCREV = "198d019583e332653d4e8dcca9439817b39b6a20"
+PV = "0.2.1"
diff --git a/dynamic-layers/meta-qt6/recipes-qt/xdg-desktop-portal-hyprland/xdg-desktop-portal-hyprland.bb b/dynamic-layers/meta-qt6/recipes-qt/xdg-desktop-portal-hyprland/xdg-desktop-portal-hyprland.bb
new file mode 100644
index 0000000..bc526c7
--- /dev/null
+++ b/dynamic-layers/meta-qt6/recipes-qt/xdg-desktop-portal-hyprland/xdg-desktop-portal-hyprland.bb
@@ -0,0 +1,35 @@
+SUMMARY = "This provides screenshot/screencast xdg-desktop-portal backends for hyprland."
+HOMEPAGE = "https://github.com/hyprwm/xdg-desktop-portal-hyprland"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e316e9609dd7672b87ff25b46b2cf3e1"
+
+# Note: meta-qt6 is needed
+DEPENDS = " \
+    wayland \
+    wayland-native \
+    wayland-protocols \
+    libdrm \
+    libinih \
+    util-linux \
+    pipewire \
+    virtual/libgbm \
+"
+
+RDEPENDS:${PN} = "hyprland-share-picker"
+RCONFLICTS:${PN} = "xdg-desktop-portal-wlr xdg-desktop-portal-gnome"
+
+inherit meson pkgconfig features_check
+REQUIRED_DISTRO_FEATURES = "opengl wayland"
+
+SRC_URI = "gitsm://github.com/hyprwm/xdg-desktop-portal-hyprland.git;protocol=https;nobranch=1"
+
+S = "${WORKDIR}/git"
+SRCREV = "4d9ff0c17716936e0b5ca577a39e263633901ed1"
+PV = "0.4.0"
+
+PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', 'basu', d)}"
+
+PACKAGECONFIG[systemd] = "-Dsystemd=enabled -Dsd-bus-provider=libsystemd,-Dsystemd=disabled,systemd"
+PACKAGECONFIG[basu] = "-Dsd-bus-provider=basu,,basu"
+
+FILES:${PN} += "${systemd_user_unitdir} ${datadir}"