From 3094f63f5a57aa3f8a05ff63877b5d53f50d2ed2 Mon Sep 17 00:00:00 2001
From: Markus Volk <f_l_k@t-online.de>
Date: Sat, 25 Nov 2023 12:33:45 +0100
Subject: [PATCH] wlroots: update

---
 recipes-wlroots/wlroots/wlroots-0.17.bb | 55 +++++++++++++++++++++++++
 recipes-wlroots/wlroots/wlroots_git.bb  |  4 +-
 2 files changed, 57 insertions(+), 2 deletions(-)
 create mode 100644 recipes-wlroots/wlroots/wlroots-0.17.bb

diff --git a/recipes-wlroots/wlroots/wlroots-0.17.bb b/recipes-wlroots/wlroots/wlroots-0.17.bb
new file mode 100644
index 0000000..8302814
--- /dev/null
+++ b/recipes-wlroots/wlroots/wlroots-0.17.bb
@@ -0,0 +1,55 @@
+SUMMARY = "A modular Wayland compositor library"
+DESCRIPTION = "Pluggable, composable, unopinionated modules for building a \
+Wayland compositor; or about 50,000 lines of code you were \
+going to write anyway."
+HOMEPAGE = "https://gitlab.freedesktop.org/wlroots"
+BUGTRACKER = "https://gitlab.freedesktop.org/wlroots/wlroots/-/issues"
+SECTION = "graphics"
+LICENSE = "MIT & CC0-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=89e064f90bcb87796ca335cbd2ce4179"
+LIC_FILES_CHKSUM += "file://tinywl/LICENSE;md5=d957da0415f5b0b974bfc6063afab2b5"
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+DEPENDS += " \
+	hwdata-native \
+	libdisplay-info \
+	libdrm \
+	libliftoff \
+	libxkbcommon \
+	pixman \
+	seatd \
+	wayland \
+	wayland-native \
+	wayland-protocols \
+"
+
+PACKAGECONFIG[opengl] = ",,virtual/egl virtual/libgles2"
+PACKAGECONFIG[gbm] = ",,virtual/libgbm"
+PACKAGECONFIG[libinput] = ",,libinput"
+PACKAGECONFIG[systemd] = ",,systemd"
+PACKAGECONFIG[sysvinit] = ",,eudev elogind"
+PACKAGECONFIG[vulkan] = ",,vulkan-loader vulkan-headers glslang-native"
+PACKAGECONFIG[x11] = ",,xcb-util-renderutil"
+PACKAGECONFIG[xwayland] = "-Dxwayland=enabled,-Dxwayland=disabled,xwayland xcb-util-wm,xwayland"
+
+PACKAGECONFIG ?= " \
+	${@bb.utils.filter('DISTRO_FEATURES', 'systemd vulkan x11 xwayland opengl', d)} \
+	libinput \
+"
+
+SRC_URI = "git://gitlab.freedesktop.org/wlroots/wlroots.git;branch=master;protocol=https"
+SRCREV = "767eedd3cbe9900687bf3b82236320dcd7b77aae"
+PV = "0.17.0"
+
+S = "${WORKDIR}/git"
+
+
+inherit meson pkgconfig features_check
+
+EXTRA_OEMESON += "--buildtype release"
+
+do_install:append() {
+	install -d ${D}${bindir}
+	install -m 0755 ${B}/tinywl/tinywl ${D}${bindir}
+}
diff --git a/recipes-wlroots/wlroots/wlroots_git.bb b/recipes-wlroots/wlroots/wlroots_git.bb
index a2811bb..fc39dd1 100644
--- a/recipes-wlroots/wlroots/wlroots_git.bb
+++ b/recipes-wlroots/wlroots/wlroots_git.bb
@@ -39,8 +39,8 @@ PACKAGECONFIG ?= " \
 "
 
 SRC_URI = "git://gitlab.freedesktop.org/wlroots/wlroots.git;branch=master;protocol=https"
-SRCREV = "47bf87ade2bd32395615a385ebde1fefbcdf79a2"
-PV = "0.17.0-dev"
+SRCREV = "36cc698bc5513655e5c57ba62693fce9001d86e7"
+PV = "0.18.0-dev"
 
 S = "${WORKDIR}/git"