sway: add recipe for sway-1.11

recipes-wlroots/sway/sway-1.11.bb

@@ -0,0 +1,65 @@
+
+SUMMARY = "A Wayland WM"
+HOMEPAGE = "https://github.com/swaywm/sway"
+BUGTRACKER = "https://github.com/swaywm/sway/issues"
+SECTION = "graphics"
+LICENSE = "MIT"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=dfc67e5b1fa10ebb4b70eb0c0ca67bea"
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+DEPENDS += " \
+	wlroots-0.19 \
+	cairo \
+	libevdev \
+	json-c \
+	libdrm \
+	libinput \
+	libxkbcommon \
+	pango \
+	pcre2 \
+	pixman \
+	virtual/libgles2 \
+	wayland \
+	wayland-native \
+	wayland-protocols \
+"
+
+RDEPENDS:${PN} = "swaybg python3 python-i3ipc"
+
+RRECOMMENDS:${PN} ?= " \
+	foot \
+	jq \
+	grim \
+	slurp \
+	wl-clipboard \
+	sway-contrib \
+"
+
+SRC_URI = "git://github.com/swaywm/sway.git;protocol=https;branch=v1.11"
+
+SRCREV = "ac54112fc77cded9c2d56a8c33abf8c2842ffbf4"
+PV = "1.11-rc3"
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig features_check
+
+PACKAGECONFIG[basu] = "-Dsd-bus-provider=basu,,basu"
+PACKAGECONFIG[default-wallpaper] = "-Ddefault-wallpaper=true,-Ddefault-wallpaper=false"
+PACKAGECONFIG[elogind] = "-Dsd-bus-provider=libelogind,,elogind"
+PACKAGECONFIG[gdk-pixbuf] = "-Dgdk-pixbuf=enabled,-Dgdk-pixbuf=disabled,gdk-pixbuf"
+PACKAGECONFIG[swaybar] = "-Dswaybar=true,-Dswaybar=false"
+PACKAGECONFIG[swaynag] = "-Dswaynag=true,-Dswaynag=false"
+PACKAGECONFIG[systemd] = "-Dsd-bus-provider=libsystemd,,systemd"
+PACKAGECONFIG[tray] = "-Dtray=enabled,-Dtray=disabled"
+
+PACKAGECONFIG ?= " \
+	${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
+	default-wallpaper \
+	gdk-pixbuf \
+"
+
+EXTRA_OEMESON += "--buildtype release"
+
+FILES:${PN} += "${datadir}"

recipes-wlroots/sway/sway_git.bb

@@ -39,8 +39,8 @@ RRECOMMENDS:${PN} ?= " \
 
 SRC_URI = "git://github.com/swaywm/sway.git;protocol=https;branch=master"
 
-SRCREV = "ab455bbadae5f115262161c165fdd46d1cc4295d"
+SRCREV = "5cfcd1c7c2ee1e0a199fd5d62b1da962f2102a85"
-PV = "1.11-dev"
+PV = "1.12-dev"
 S = "${WORKDIR}/git"
 
 inherit meson pkgconfig features_check