sort gtk recipes

recipes-gtk/gimp/gimp/0001-meson-make-gir-buildable.patch

@@ -0,0 +1,43 @@
+From c8f73f57d63779cfaad140e0521be40972fbec8f Mon Sep 17 00:00:00 2001
+From: Markus Volk <f_l_k@t-online.de>
+Date: Wed, 1 Sep 2021 16:44:13 +0200
+Subject: [PATCH] meson: make gir buildable
+
+yocto/oe is capable of building gobject introspection despite cross-compiling.
+add an option to enable gir build even if cross-compiling
+
+Signed-off-by: Markus Volk <f_l_k@t-online.de>
+---
+ libgimp/meson.build | 2 +-
+ meson_options.txt   | 2 +-
+ 2 files changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/libgimp/meson.build b/libgimp/meson.build
+index 9e7b4fbbe3..99614733d7 100644
+--- a/libgimp/meson.build
++++ b/libgimp/meson.build
+@@ -384,7 +384,7 @@ libgimpui_introspectable_files = [
+   libgimpwidgets_introspectable,
+ ]
+ 
+-if meson.is_cross_build()
++if meson.is_cross_build() and not get_option('introspection')
+   have_gobject_introspection = false
+   gobject_introspection_warning = '\n      '.join(['',
+     'GObject Introspection is disabled while cross-compiling because',
+diff --git a/meson_options.txt b/meson_options.txt
+index 7b6ad78045..c29fdb5b40 100644
+--- a/meson_options.txt
++++ b/meson_options.txt
+@@ -52,7 +52,7 @@ option('headless-tests',    type: 'feature', value: 'auto', description: 'Use xv
+ option('gtk-doc',           type: 'boolean', value: true,   description: 'Build developer documentation')
+ option('gtk-doc-app',       type: 'boolean', value: false,  description: 'Build developer documentation for app')
+ option('g-ir-doc',          type: 'boolean', value: false,  description: 'Build developer documentation for introspected API')
+-
++option('introspection',   type: 'boolean', value: false,  description: 'GIR is buildable even if crosscompiling')
+ option('linux-input',       type: 'feature', value: 'auto', description: 'Linux input event controller module')
+ option('vec-icons',         type: 'boolean', value: true,   description: 'Use vector icons rather than raster ones')
+ 
+-- 
+2.25.1
+

recipes-gtk/gimp/gimp_2.99.6.bb

@@ -0,0 +1,110 @@
+SUMMARY = "The GIMP is the GNU Image Manipulation Program"
+HOMEPAGE = "http://www.gimp.org"
+SECTION = "graphics"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c678957b0c8e964aa6c70fd77641a71e"
+
+REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
+
+DEPENDS = " \
+    appstream-glib \
+    atk \
+    babl \
+    bison-native \
+    cairo \
+    dbus-glib \
+    fontconfig \
+    freetype \
+    gdk-pixbuf-native \
+    gegl \
+    gegl-native \
+    gexiv2 \
+    gtk+3 \
+    harfbuzz \
+    intltool-native \
+    json-glib \
+    lcms \
+    libarchive \
+    libexif \
+    libmypaint \
+    libxslt-native \
+    mypaint-brushes-1.0 \
+    pango \
+    poppler \
+    poppler-data \
+"
+
+DEPENDS:append:libc-musl = " libexecinfo"
+RDEPENDS:${PN} = "mypaint-brushes-1.0 glib-networking"
+
+inherit meson gtk-icon-cache mime-xdg pkgconfig features_check gobject-introspection
+
+SRC_URI = " \
+    git://github.com/GNOME/gimp.git;protocol=https \
+    file://0001-meson-make-gir-buildable.patch \
+"
+
+S = "${WORKDIR}/git"
+SRCREV = "GIMP_2_99_6"
+
+PACKAGECONFIG[aa] = "-Daa=enabled,-Daa=disabled,aalib"
+PACKAGECONFIG[alsa] = "-Dalsa=enabled,-Dalsa=disabled,alsa-lib"
+PACKAGECONFIG[appdata-test] = "-Dappdata-test=enabled,-Dappdata-test=disabled,appstream-glib-native"
+PACKAGECONFIG[bzip2] = ",,bzip2"
+PACKAGECONFIG[cairo-pdf] = "-Dcairo-pdf=enabled,-Dcairo-pdf=disabled"
+PACKAGECONFIG[check-update] = "-Dcheck-update=true,-Dcheck-update=false"
+PACKAGECONFIG[enable-console-bin] = "-Denable-console-bin=true,-Denable-console-bin=false"
+PACKAGECONFIG[ghostscript] = "-Dghostscript=enabled,-Dghostscript=disabled,ghostscript"
+PACKAGECONFIG[gtk-doc] = "-Dgtk-doc=true,-Dgtk-doc=false,gtk-doc-native"
+PACKAGECONFIG[gtk-doc-app] = "-Dgtk-doc-app=true,-Dgtk-doc-app=false,gtk-doc-native"
+PACKAGECONFIG[gudev] = "-Dgudev=enabled,-Dgudev=disabled,libgudev"
+PACKAGECONFIG[javascript] = "-Djavascript=true,-Djavascript=false,,openjre-8"
+PACKAGECONFIG[jpeg2000] = "-Djpeg2000=enabled,-Djpeg2000=disabled,jasper"
+PACKAGECONFIG[jpeg] = ",,jpeg"
+PACKAGECONFIG[lua] = "-Dlua=true,-Dlua=false,,luajit lgi"
+PACKAGECONFIG[lzma] = ",,xz"
+PACKAGECONFIG[mng] = "-Dmng=enabled,-Dmng=disabled,libmng"
+PACKAGECONFIG[png] = "-Dpng=enabled,-Dpng=disabled,libpng"
+PACKAGECONFIG[python] = "-Dpython=true,-Dpython=false,,python3 python3-pygobject"
+PACKAGECONFIG[rsvg] = ",,librsvg"
+PACKAGECONFIG[tiff] = ",,tiff"
+PACKAGECONFIG[vala-plugins] = "-Dvala-plugins=enabled,-Dvala-plugins=disabled"
+PACKAGECONFIG[webkit] = "-Dwebkit=enabled,-Dwebkit=disabled,webkitgtk"
+PACKAGECONFIG[webp] = "-Dwebp=enabled,-Dwebp=disabled,libwebp"
+PACKAGECONFIG[xcursor] = "-Dxcursor=enabled,-Dxcursor=disabled,libxcursor"
+PACKAGECONFIG[x11] = "-Dxpm=enabled,-Dxpm=disabled,libxpm libxmu"
+PACKAGECONFIG[zlib] = ",,zlib"
+
+PACKAGECONFIG ?= " \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} \
+    aa \
+    alsa \
+    bzip2 \
+    cairo-pdf \
+    gtk-doc-app \
+    gudev \
+    jpeg \
+    jpeg2000 \
+    lua \
+    lzma \
+    mng \
+    png \
+    python \
+    rsvg \
+    tiff \
+    webp \
+    zlib \
+"
+
+FILES:${PN} += " \
+    ${datadir}/metainfo \
+    ${datadir}/gir-1.0 \
+    ${datadir}/appdata \ 
+    ${libdir}/girepository-1.0 \
+"
+
+EXTRA_OEMESON += " \
+    -Dshmem-type=posix \
+    --buildtype release \
+"
+

recipes-gtk/gtk-layer-shell/gtk-layer-shell_git.bb

@@ -0,0 +1,33 @@
+SUMMARY = "A library to write GTK applications that use Layer Shell"
+DESCRIPTION = "A library to write GTK applications that use Layer Shell. Layer Shell is a Wayland protocol for desktop shell components, such as panels, notifications and wallpapers."
+AUTHOR = ""
+HOMEPAGE = "https://github.com/wmww/gtk-layer-shell"
+BUGTRACKER = "https://github.com/www/gtk-layer-shell/issues"
+SECTION = "graphics"
+LICENSE = "MIT"
+
+LIC_FILES_CHKSUM = "file://LICENSE_MIT.txt;md5=d015f272ca1521139fd99ea64d6e5e23"
+
+REQUIRED_DISTRO_FEATURES = "wayland gobject-introspection-data"
+
+DEPENDS += " \
+	gtk+3 \
+	wayland \
+	wayland-native \
+	gobject-introspection \
+	gobject-introspection-native \
+	qemu-native \
+	prelink-native \
+"
+
+SRC_URI = "git://github.com/wmww/gtk-layer-shell.git;protocol=https"
+
+S = "${WORKDIR}/git"
+PV = "0.6.0"
+SRCREV = "v${PV}"
+
+inherit meson pkgconfig features_check
+FILES:${PN} = "${datadir} ${libdir}"
+
+BBCLASSEXTEND = ""
+

recipes-gtk/nwg-shell/azote_git.bb

@@ -0,0 +1,41 @@
+SUMMARY = "Azote is a GTK+3 based frontend for swaybg."
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=1ebbd3e34237af26da5dc08a4e440464"
+
+SRC_URI = " \
+	git://github.com/nwg-piotr/azote.git;protocol=https \
+"
+
+RDEPENDS:${PN} = " \
+	python3 \
+	gtk+3 \
+	python3-pygobject \
+	python3-pycairo \
+	python3-pillow \
+	python3-pkg-resources \
+	python3-send2trash \
+	imagemagick \
+	grim \
+	slurp \
+	swaybg \
+"
+
+inherit setuptools3
+
+S = "${WORKDIR}/git"
+PV = "1.9.1"
+SRCREV = "v${PV}"
+
+do_install:append() {
+	install -d ${D}${bindir} ${D}${datadir}/azote ${D}${datadir}/pixmaps ${D}${datadir}/applications
+	install -m 755 ${S}/dist/azote ${D}${bindir}
+	install -m 644 ${S}/dist/azote.desktop ${D}${datadir}/applications
+	install -m 644 ${S}/dist/azote.svg ${D}${datadir}/pixmaps
+	install -m 644 ${S}/dist/indicator_active.png ${D}${datadir}/azote
+	install -m 644 ${S}/dist/indicator_attention.png ${D}${datadir}/azote
+}
+
+FILES:${PN}:append = " \
+	${datadir} \
+	${bindir} \
+"

recipes-gtk/nwg-shell/nwg-bar_git.bb

@@ -0,0 +1,26 @@
+SUMMARY = "nwg-bar for wlroots based compositors."
+DESCRIPTION = "The nwg-bar command creates a button bar on the basis of a JSON template placed in the ~/.config/nwg-bar/ folder."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://src/${GO_IMPORT}/LICENSE;md5=fffa55ad1c828db5e334374fb1182530"
+
+DEPENDS = " \
+	gtk+3 \
+	gtk-layer-shell \
+"
+
+GO_IMPORT = "github.com/nwg-piotr/nwg-bar.git"
+
+SRC_URI = "git://${GO_IMPORT};nobranch=1"
+
+PV = "0.0.1"
+SRCREV = "v${PV}"
+
+inherit go go-mod
+
+GO_INSTALL = "${GO_IMPORT}"
+
+do_install:append() {
+	# remove precompiled x86 binary
+	rm -r ${D}${libdir}/go/src/${GO_IMPORT}/bin
+}
+

recipes-gtk/nwg-shell/nwg-dock_git.bb

@@ -0,0 +1,26 @@
+SUMMARY = "GTK3-based dock for wlroots based compositors."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://src/${GO_IMPORT}/LICENSE;md5=fffa55ad1c828db5e334374fb1182530"
+
+DEPENDS = " \
+	gtk+3 \
+	gtk-layer-shell \
+"
+
+GO_IMPORT = "github.com/nwg-piotr/nwg-dock.git"
+
+SRC_URI = "git://${GO_IMPORT};nobranch=1"
+
+PV = "0.1.6"
+SRCREV = "v${PV}"
+
+inherit go go-mod
+
+GO_INSTALL = "${GO_IMPORT}"
+
+do_install:append() {
+	# remove precompiled x86 binaries
+	rm -r ${D}${libdir}/go/src/${GO_IMPORT}/bin
+	rm -r ${D}${libdir}/go/pkg/mod/github.com/dlasky/gotk3-layershell*/example
+}
+

recipes-gtk/nwg-shell/nwg-drawer_git.bb

@@ -0,0 +1,30 @@
+SUMMARY = "GTK3-based application launcher for wlroots based compositors."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://src/${GO_IMPORT}/LICENSE;md5=fffa55ad1c828db5e334374fb1182530"
+
+DEPENDS = " \
+	gtk+3 \
+	gtk-layer-shell \
+"
+
+RRECOMMENDS:${PN} = " \
+	thunar \
+	foot \
+"
+
+GO_IMPORT = "github.com/nwg-piotr/nwg-drawer.git"
+
+SRC_URI = "git://${GO_IMPORT};nobranch=1"
+
+PV = "0.1.11"
+SRCREV = "v${PV}"
+
+inherit go go-mod pkgconfig
+
+GO_INSTALL = "${GO_IMPORT}"
+
+do_install:append() {
+	# remove precompiled x86 binary
+	rm -r ${D}${libdir}/go/src/${GO_IMPORT}/bin
+}
+

recipes-gtk/nwg-shell/nwg-launchers_git.bb

@@ -0,0 +1,40 @@
+SUMMARY = "nwg-launchers written in c++"
+HOMEPAGE = "https://github.com/nwg-piotr/nwg-launchers"
+BUGTRACKER = "https://github.com/nwg-piotr/nwg-launchers/issues"
+SECTION = "graphics"
+LICENSE = "MIT"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=1ebbd3e34237af26da5dc08a4e440464"
+
+DEPENDS += " \
+	gtkmm3 \
+	nlohmann-json \
+"
+
+PACKAGECONFIG[bar] = "-Dbar=true,-Dbar=false"
+PACKAGECONFIG[dmenu] = "-Ddmenu=true,-Ddmenu=false"
+PACKAGECONFIG[grid] = "-Dgrid=true,-Dgrid=false"
+PACKAGECONFIG[layer-shell] = "-Dlayer-shell=enabled,-Dlayer-shell=disabled,gtk-layer-shell"
+PACKAGECONFIG[gdk-x11] = "-Dgdk-x11=enabled,-Dgdk-x11=disabled"
+
+PACKAGECONFIG ?= " \
+	bar \
+	dmenu \
+	grid \
+	layer-shell \
+"
+
+SRC_URI = " \
+	git://github.com/nwg-piotr/nwg-launchers.git;protocol=https \
+"
+SRCREV = "v${PV}"
+PV = "0.6.1"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig
+
+EXTRA_OEMESON += "--buildtype release"
+
+BBCLASSEXTEND = ""
+

recipes-gtk/nwg-shell/nwg-menu_git.bb

@@ -0,0 +1,32 @@
+SUMMARY = "MenuStart plugin to nwg-panel."
+DESCRIPTION = "This code provides the MenuStart plugin to nwg-panel. It \
+also may be used standalone with a little help from command line arguments."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://src/${GO_IMPORT}/LICENSE;md5=fffa55ad1c828db5e334374fb1182530"
+
+DEPENDS = " \
+	gtk+3 \
+	gtk-layer-shell \
+"
+
+RRECOMMENDS:${PN} = " \
+	thunar \
+	foot \
+"
+
+GO_IMPORT = "github.com/nwg-piotr/nwg-menu.git"
+
+SRC_URI = "git://${GO_IMPORT};nobranch=1"
+
+PV = "0.1.1"
+SRCREV = "v${PV}"
+
+inherit go go-mod
+
+GO_INSTALL = "${GO_IMPORT}"
+
+do_install:append() {
+	# remove precompiled x86 binary
+	rm -r ${D}${libdir}/go/src/${GO_IMPORT}/bin
+}
+

recipes-gtk/nwg-shell/nwg-panel_git.bb

@@ -0,0 +1,28 @@
+SUMMARY = "GTK3-based panel for wayland."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=fffa55ad1c828db5e334374fb1182530"
+
+SRC_URI = " \
+	git://github.com/nwg-piotr/nwg-panel.git;protocol=https \
+"
+
+RDEPENDS:${PN} = "\
+	light \
+	python3 \
+	python3-pygobject \
+	python3-psutil \
+	python-i3ipc \
+"
+
+inherit setuptools3
+
+S = "${WORKDIR}/git"
+PV = "0.4.3"
+SRCREV = "v${PV}"
+
+do_install:append() {
+	rm  ${D}${libdir}/python3.9/site-packages/nwg_panel/executors/arch_updates.py
+}
+
+INSANE_SKIP:${PN} = "file-rdeps"
+

recipes-gtk/nwg-shell/nwg-wrapper_git.bb

@@ -0,0 +1,17 @@
+SUMMARY = "GTK3-based wrapper to display a script output, or a text file content on the desktop in wlroots-based compositors."
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=fffa55ad1c828db5e334374fb1182530"
+
+SRC_URI = " \
+	git://github.com/nwg-piotr/nwg-wrapper.git;protocol=https \
+"
+
+DEPENDS = "python3"
+RDEPENDS:${PN} = "python3-pygobject"
+
+inherit setuptools3 gobject-introspection
+
+S = "${WORKDIR}/git"
+PV = "0.0.2"
+SRCREV = "v${PV}"
+

recipes-gtk/waybar/waybar_git.bb

@@ -0,0 +1,65 @@
+SUMMARY = "Wayland bar for Wlroots based compositors"
+DESCRIPTION = "Highly customizable Wayland bar for Sway and Wlroots based compositors."
+AUTHOR = ""
+HOMEPAGE = "https://github.com/Alexays/Waybar"
+BUGTRACKER = "https://github.com/Alexays/Waybar/issues"
+SECTION = "graphics"
+LICENSE = "MIT"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=98f7e9dc79966298d76caf1b0a6d35c1"
+
+REQUIRED_DISTRO_FEATURES = "wayland gobject-introspection-data"
+
+DEPENDS += " \
+	fmt \
+	glib-2.0-native \
+	gtkmm3 \
+	jsoncpp \
+	libevdev \
+	libsigc++-3 \
+	libxkbcommon \
+	gtk+3 \
+	gobject-introspection \
+	spdlog \
+	wayland \
+	wayland-native \
+	wayland-protocols \
+"
+
+PACKAGECONFIG[bluetooth] = "-Drfkill=enabled,-Drfkill=disabled"
+PACKAGECONFIG[date] = ",,date"
+PACKAGECONFIG[pulseaudio] = ",,pulseaudio"
+PACKAGECONFIG[gtk-layer-shell] = ",,gtk-layer-shell"
+PACKAGECONFIG[mpd] = ",,libmpdclient"
+PACKAGECONFIG[network] = ",,libnl"
+PACKAGECONFIG[sysvinit] = ",,eudev"
+PACKAGECONFIG[systemd] = ",,systemd"
+
+PACKAGECONFIG ?= " \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'bluetooth', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'sysvinit', d)} \
+    network \
+    gtk-layer-shell \
+    date \
+"
+
+RRECOMMENDS:${PN} += " \
+	font-awesome-otf \
+"
+
+SRC_URI = "git://github.com/Alexays/Waybar.git;protocol=https"
+
+S = "${WORKDIR}/git"
+PV = "0.9.8+${SRCREV}"
+SRCREV = "cee08eccd116ede5c648b5e7dd03735a3cf3b42e"
+
+inherit meson pkgconfig features_check
+
+PACKAGES += "${PN}-systemd"
+
+FILES:${PN}-systemd += "${libdir}/systemd"
+
+BBCLASSEXTEND = ""
+