mirror of
https://github.com/linux-sunxi/meta-sunxi.git
synced 2024-07-03 12:39:48 +02:00
6ece692e9b
For some reason it was not updated since 2015 and there seem to be quite some changes in the repo. Also switch protocol for getting sources from GitHub from git to https to get rid of the bitbake warning. Signed-off-by: Alexey Brodkin <alexey.brodkin@gmail.com>
48 lines
1.4 KiB
BlitzBasic
48 lines
1.4 KiB
BlitzBasic
# Copyright (C) 2013 Tomas Novotny <novotny@rehivetech.com>
|
|
# Released under BSD-2-Clause or MIT license
|
|
DESCRIPTION = "Handler for Allwinner's FEX files"
|
|
LICENSE = "CC0-1.0"
|
|
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/${LICENSE};md5=0ceb3372c9595f0a8067e55da801e4a1"
|
|
DEPENDS = "sunxi-tools-native"
|
|
PV = "1.1+git${SRCPV}"
|
|
PR = "r0"
|
|
|
|
COMPATIBLE_MACHINE = "(sun4i|sun5i|sun7i)"
|
|
|
|
SRC_URI = "git://github.com/linux-sunxi/sunxi-boards.git;protocol=https;branch=master"
|
|
# Increase PV with SRCREV change
|
|
SRCREV = "af5f938ea14a3614d35ad3d9ab51a5d392117444"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
SUNXI_FEX_BIN_IMAGE = "fex-${MACHINE}-${PV}-${PR}.bin"
|
|
SUNXI_FEX_BIN_IMAGE_SYMLINK = "fex-${MACHINE}.bin"
|
|
SUNXI_FEX_BIN_IMAGE_SYMLINK_SIMPLE = "fex.bin"
|
|
|
|
inherit deploy
|
|
|
|
do_compile() {
|
|
fex2bin "${S}/${SUNXI_FEX_FILE}" > "${B}/${SUNXI_FEX_BIN_IMAGE}"
|
|
}
|
|
|
|
do_deploy() {
|
|
install -m 0644 ${B}/${SUNXI_FEX_BIN_IMAGE} ${DEPLOYDIR}/
|
|
cd ${DEPLOYDIR}
|
|
ln -sf ${SUNXI_FEX_BIN_IMAGE} ${SUNXI_FEX_BIN_IMAGE_SYMLINK}
|
|
ln -sf ${SUNXI_FEX_BIN_IMAGE} ${SUNXI_FEX_BIN_IMAGE_SYMLINK_SIMPLE}
|
|
}
|
|
addtask deploy before do_build after do_compile
|
|
|
|
PACKAGES = ""
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
do_install[noexec] = "1"
|
|
do_package[noexec] = "1"
|
|
do_packagedata[noexec] = "1"
|
|
do_package_write[noexec] = "1"
|
|
do_package_write_ipk[noexec] = "1"
|
|
do_package_write_rpm[noexec] = "1"
|
|
do_package_write_deb[noexec] = "1"
|
|
do_populate_sysroot[noexec] = "1"
|