mirror of
https://github.com/linux-sunxi/meta-sunxi.git
synced 2024-12-28 05:58:21 +01:00
52 lines
1.6 KiB
BlitzBasic
52 lines
1.6 KiB
BlitzBasic
# Copyright (C) 2013 Tomas Novotny <novotny@rehivetech.com>
|
|
# Released under BSD-2-Clause or MIT license
|
|
DESCRIPTION = "Handler for Allwinner's FEX files"
|
|
LICENSE = "CC0-1.0"
|
|
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/${LICENSE};md5=0ceb3372c9595f0a8067e55da801e4a1"
|
|
DEPENDS = "sunxi-tools-native"
|
|
SRCREV = "c9f031fb2d30101cda5a988c66715101bc3fea0b"
|
|
PV = "1.0"
|
|
PR = "r3"
|
|
|
|
SRC_URI = "git://github.com/linux-sunxi/sunxi-boards.git;protocol=git"
|
|
|
|
S = "${WORKDIR}/git"
|
|
SUNXI_FEX_FILE_olinuxino-a10s = "sys_config/a10s/a10s-olinuxino-m.fex"
|
|
SUNXI_FEX_FILE_cubieboard = "sys_config/a10/cubieboard.fex"
|
|
SUNXI_FEX_FILE_cubieboard2 = "sys_config/a20/cubieboard2.fex"
|
|
|
|
SUNXI_FEX_BIN_IMAGE = "fex-${MACHINE}-${PV}-${PR}.bin"
|
|
SUNXI_FEX_BIN_IMAGE_SYMLINK = "fex-${MACHINE}.bin"
|
|
SUNXI_FEX_BIN_IMAGE_SYMLINK_SIMPLE = "fex.bin"
|
|
|
|
inherit deploy
|
|
|
|
do_compile() {
|
|
fex2bin "${S}/${SUNXI_FEX_FILE}" > "${B}/${SUNXI_FEX_BIN_IMAGE}"
|
|
}
|
|
|
|
do_deploy() {
|
|
install -m 0644 ${B}/${SUNXI_FEX_BIN_IMAGE} ${DEPLOYDIR}/
|
|
cd ${DEPLOYDIR}
|
|
ln -sf ${SUNXI_FEX_BIN_IMAGE} ${SUNXI_FEX_BIN_IMAGE_SYMLINK}
|
|
ln -sf ${SUNXI_FEX_BIN_IMAGE} ${SUNXI_FEX_BIN_IMAGE_SYMLINK_SIMPLE}
|
|
}
|
|
addtask deploy before do_build after do_compile
|
|
|
|
PACKAGES = ""
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
do_install[noexec] = "1"
|
|
do_package[noexec] = "1"
|
|
do_packagedata[noexec] = "1"
|
|
do_package_write[noexec] = "1"
|
|
do_package_write_ipk[noexec] = "1"
|
|
do_package_write_rpm[noexec] = "1"
|
|
do_package_write_deb[noexec] = "1"
|
|
do_populate_sysroot[noexec] = "1"
|
|
|
|
# Remember to add machine entry to IMAGE_DEPENDS in sdcard_image-a10.bbclass
|
|
# when adding new machines.
|
|
COMPATIBLE_MACHINE = "(olinuxino-a10s|cubieboard|cubieboard2)"
|