mirror of
https://github.com/linux-sunxi/meta-sunxi.git
synced 2024-11-16 18:28:23 +01:00
123 lines
4.2 KiB
PHP
123 lines
4.2 KiB
PHP
SUMMARY = "Universal Boot Loader for embedded devices"
|
|
HOMEPAGE = "http://www.denx.de/wiki/U-Boot/WebHome"
|
|
SECTION = "bootloaders"
|
|
PROVIDES = "virtual/bootloader"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1707d6db1d42237583f50183a5651ecb \
|
|
file://README;beginline=1;endline=22;md5=78b195c11cb6ef63e6985140db7d7bab"
|
|
|
|
SRC_URI = "git://git.denx.de/u-boot.git;branch=master"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
inherit uboot-config deploy
|
|
|
|
EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
|
|
|
|
# Allow setting an additional version string that will be picked up by the
|
|
# u-boot build system and appended to the u-boot version. If the .scmversion
|
|
# file already exists it will not be overwritten.
|
|
UBOOT_LOCALVERSION ?= ""
|
|
|
|
# Some versions of u-boot use .bin and others use .img. By default use .bin
|
|
# but enable individual recipes to change this value.
|
|
UBOOT_SUFFIX ?= "bin"
|
|
UBOOT_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}"
|
|
UBOOT_BINARY ?= "u-boot.${UBOOT_SUFFIX}"
|
|
UBOOT_SYMLINK ?= "u-boot-${MACHINE}.${UBOOT_SUFFIX}"
|
|
UBOOT_MAKE_TARGET ?= "all"
|
|
|
|
# Some versions of u-boot build an SPL (Second Program Loader) image that
|
|
# should be packaged along with the u-boot binary as well as placed in the
|
|
# deploy directory. For those versions they can set the following variables
|
|
# to allow packaging the SPL.
|
|
SPL_BINARY ?= ""
|
|
SPL_IMAGE ?= "${SPL_BINARY}-${MACHINE}-${PV}-${PR}"
|
|
SPL_SYMLINK ?= "${SPL_BINARY}-${MACHINE}"
|
|
|
|
# Additional environment variables or a script can be installed alongside
|
|
# u-boot to be used automatically on boot. This file, typically 'uEnv.txt'
|
|
# or 'boot.scr', should be packaged along with u-boot as well as placed in the
|
|
# deploy directory. Machine configurations needing one of these files should
|
|
# include it in the SRC_URI and set the UBOOT_ENV parameter.
|
|
UBOOT_ENV_SUFFIX ?= "txt"
|
|
UBOOT_ENV ?= ""
|
|
UBOOT_ENV_BINARY ?= "${UBOOT_ENV}.${UBOOT_ENV_SUFFIX}"
|
|
UBOOT_ENV_IMAGE ?= "${UBOOT_ENV}-${MACHINE}-${PV}-${PR}.${UBOOT_ENV_SUFFIX}"
|
|
UBOOT_ENV_SYMLINK ?= "${UBOOT_ENV}-${MACHINE}.${UBOOT_ENV_SUFFIX}"
|
|
|
|
do_compile () {
|
|
if [ "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then
|
|
sed -i 's/$(CROSS_COMPILE)ld$/$(CROSS_COMPILE)ld.bfd/g' config.mk
|
|
fi
|
|
|
|
unset LDFLAGS
|
|
unset CFLAGS
|
|
unset CPPFLAGS
|
|
|
|
if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ]
|
|
then
|
|
echo ${UBOOT_LOCALVERSION} > ${B}/.scmversion
|
|
echo ${UBOOT_LOCALVERSION} > ${S}/.scmversion
|
|
fi
|
|
|
|
oe_runmake ${UBOOT_MACHINE}
|
|
oe_runmake ${UBOOT_MAKE_TARGET}
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}/boot
|
|
install ${S}/${UBOOT_BINARY} ${D}/boot/${UBOOT_IMAGE}
|
|
ln -sf ${UBOOT_IMAGE} ${D}/boot/${UBOOT_BINARY}
|
|
|
|
if [ -e ${WORKDIR}/fw_env.config ] ; then
|
|
install -d ${D}${sysconfdir}
|
|
install -m 644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
|
|
fi
|
|
|
|
if [ "x${SPL_BINARY}" != "x" ]
|
|
then
|
|
install ${S}/${SPL_BINARY} ${D}/boot/${SPL_IMAGE}
|
|
ln -sf ${SPL_IMAGE} ${D}/boot/${SPL_BINARY}
|
|
fi
|
|
|
|
if [ "x${UBOOT_ENV}" != "x" ]
|
|
then
|
|
install ${WORKDIR}/${UBOOT_ENV_BINARY} ${D}/boot/${UBOOT_ENV_IMAGE}
|
|
ln -sf ${UBOOT_ENV_IMAGE} ${D}/boot/${UBOOT_ENV_BINARY}
|
|
fi
|
|
}
|
|
|
|
FILES_${PN} = "/boot ${sysconfdir}"
|
|
|
|
do_deploy () {
|
|
install -d ${DEPLOYDIR}
|
|
install ${S}/${UBOOT_BINARY} ${DEPLOYDIR}/${UBOOT_IMAGE}
|
|
|
|
cd ${DEPLOYDIR}
|
|
rm -f ${UBOOT_BINARY} ${UBOOT_SYMLINK}
|
|
ln -sf ${UBOOT_IMAGE} ${UBOOT_SYMLINK}
|
|
ln -sf ${UBOOT_IMAGE} ${UBOOT_BINARY}
|
|
|
|
if [ "x${SPL_BINARY}" != "x" ]
|
|
then
|
|
install ${S}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_IMAGE}
|
|
rm -f ${DEPLOYDIR}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_SYMLINK}
|
|
ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_BINARY}
|
|
ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_SYMLINK}
|
|
fi
|
|
|
|
if [ "x${UBOOT_ENV}" != "x" ]
|
|
then
|
|
install ${WORKDIR}/${UBOOT_ENV_BINARY} ${DEPLOYDIR}/${UBOOT_ENV_IMAGE}
|
|
rm -f ${DEPLOYDIR}/${UBOOT_ENV_BINARY} ${DEPLOYDIR}/${UBOOT_ENV_SYMLINK}
|
|
ln -sf ${UBOOT_ENV_IMAGE} ${DEPLOYDIR}/${UBOOT_ENV_BINARY}
|
|
ln -sf ${UBOOT_ENV_IMAGE} ${DEPLOYDIR}/${UBOOT_ENV_SYMLINK}
|
|
fi
|
|
}
|
|
|
|
addtask deploy before do_build after do_compile
|