mirror of
https://github.com/linux-sunxi/meta-sunxi.git
synced 2024-11-16 18:28:23 +01:00
98 lines
3.1 KiB
PHP
98 lines
3.1 KiB
PHP
|
DESCRIPTION = "U-Boot - the Universal Boot Loader"
|
||
|
|
HOMEPAGE = "http://www.denx.de/wiki/U-Boot/WebHome"
|
||
|
|
SECTION = "bootloaders"
|
||
|
|
PROVIDES = "virtual/bootloader"
|
||
|
|
|
||
|
|
inherit deploy
|
||
|
|
|
||
|
|
EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
|
||
|
|
|
||
|
|
python () {
|
||
|
|
if not d.getVar("UBOOT_MACHINE", True):
|
||
|
|
PN = d.getVar("PN", True)
|
||
|
|
FILE = os.path.basename(d.getVar("FILE", True))
|
||
|
|
bb.debug(1, "To build %s, see %s for instructions on \
|
||
|
|
setting up your machine config" % (PN, FILE))
|
||
|
|
raise bb.parse.SkipPackage("because UBOOT_MACHINE is not set")
|
||
|
|
}
|
||
|
|
|
||
|
|
# Allow setting an additional version string that will be picked up by the
|
||
|
|
# u-boot build system and appended to the u-boot version. If the .scmversion
|
||
|
|
# file already exists it will not be overwritten.
|
||
|
|
UBOOT_LOCALVERSION ?= ""
|
||
|
|
|
||
|
|
# Some versions of u-boot use .bin and others use .img. By default use .bin
|
||
|
|
# but enable individual recipes to change this value.
|
||
|
|
UBOOT_SUFFIX ?= "bin"
|
||
|
|
UBOOT_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}"
|
||
|
|
UBOOT_BINARY ?= "u-boot.${UBOOT_SUFFIX}"
|
||
|
|
UBOOT_SYMLINK ?= "u-boot-${MACHINE}.${UBOOT_SUFFIX}"
|
||
|
|
UBOOT_MAKE_TARGET ?= "all"
|
||
|
|
|
||
|
|
# Some versions of u-boot build an SPL (Second Program Loader) image that
|
||
|
|
# should be packaged along with the u-boot binary as well as placed in the
|
||
|
|
# deploy directory. For those versions they can set the following variables
|
||
|
|
# to allow packaging the SPL.
|
||
|
|
SPL_BINARY ?= ""
|
||
|
|
SPL_IMAGE ?= "${SPL_BINARY}-${MACHINE}-${PV}-${PR}"
|
||
|
|
SPL_SYMLINK ?= "${SPL_BINARY}-${MACHINE}"
|
||
|
|
|
||
|
|
do_compile () {
|
||
|
|
if [ "${@base_contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then
|
||
|
|
sed -i 's/$(CROSS_COMPILE)ld$/$(CROSS_COMPILE)ld.bfd/g' config.mk
|
||
|
|
fi
|
||
|
|
|
||
|
|
unset LDFLAGS
|
||
|
|
unset CFLAGS
|
||
|
|
unset CPPFLAGS
|
||
|
|
|
||
|
|
if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ]
|
||
|
|
then
|
||
|
|
echo ${UBOOT_LOCALVERSION} > ${B}/.scmversion
|
||
|
|
echo ${UBOOT_LOCALVERSION} > ${S}/.scmversion
|
||
|
|
fi
|
||
|
|
|
||
|
|
oe_runmake ${UBOOT_MACHINE}
|
||
|
|
oe_runmake ${UBOOT_MAKE_TARGET}
|
||
|
|
}
|
||
|
|
|
||
|
|
do_install () {
|
||
|
|
install -d ${D}/boot
|
||
|
|
install ${S}/${UBOOT_BINARY} ${D}/boot/${UBOOT_IMAGE}
|
||
|
|
ln -sf ${UBOOT_IMAGE} ${D}/boot/${UBOOT_BINARY}
|
||
|
|
|
||
|
|
if [ -e ${WORKDIR}/fw_env.config ] ; then
|
||
|
|
install -d ${D}${sysconfdir}
|
||
|
|
install -m 644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
|
||
|
|
fi
|
||
|
|
|
||
|
|
if [ "x${SPL_BINARY}" != "x" ]
|
||
|
|
then
|
||
|
|
install ${S}/${SPL_BINARY} ${D}/boot/${SPL_IMAGE}
|
||
|
|
ln -sf ${SPL_IMAGE} ${D}/boot/${SPL_BINARY}
|
||
|
|
fi
|
||
|
|
}
|
||
|
|
|
||
|
|
FILES_${PN} = "/boot ${sysconfdir}"
|
||
|
|
FILESPATH =. "${FILE_DIRNAME}/u-boot-git/${MACHINE}:"
|
||
|
|
|
||
|
|
do_deploy () {
|
||
|
|
install -d ${DEPLOYDIR}
|
||
|
|
install ${S}/${UBOOT_BINARY} ${DEPLOYDIR}/${UBOOT_IMAGE}
|
||
|
|
|
||
|
|
cd ${DEPLOYDIR}
|
||
|
|
rm -f ${UBOOT_BINARY} ${UBOOT_SYMLINK}
|
||
|
|
ln -sf ${UBOOT_IMAGE} ${UBOOT_SYMLINK}
|
||
|
|
ln -sf ${UBOOT_IMAGE} ${UBOOT_BINARY}
|
||
|
|
|
||
|
|
if [ "x${SPL_BINARY}" != "x" ]
|
||
|
|
then
|
||
|
|
install ${S}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_IMAGE}
|
||
|
|
rm -f ${DEPLOYDIR}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_SYMLINK}
|
||
|
|
ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_BINARY}
|
||
|
|
ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_SYMLINK}
|
||
|
|
fi
|
||
|
|
}
|
||
|
|
|
||
|
|
addtask deploy before do_build after do_compile
|