mirror of
https://github.com/lxsang/antd-lua-plugin
synced 2025-07-15 13:29:45 +02:00
mimgrating from another repo
This commit is contained in:
Xuan Sang LE
465
lib/ann/fann/docs/NaturalDocs-1.52/Modules/NaturalDocs/Parser/JavaDoc.pm
Executable file
465
lib/ann/fann/docs/NaturalDocs-1.52/Modules/NaturalDocs/Parser/JavaDoc.pm
Executable file
@ -0,0 +1,465 @@
|
||||
###############################################################################
|
||||
#
|
||||
# Package: NaturalDocs::Parser::JavaDoc
|
||||
#
|
||||
###############################################################################
|
||||
#
|
||||
# A package for translating JavaDoc topics into Natural Docs.
|
||||
#
|
||||
# Supported tags:
|
||||
#
|
||||
# - @param
|
||||
# - @author
|
||||
# - @deprecated
|
||||
# - @code, @literal (doesn't change font)
|
||||
# - @exception, @throws (doesn't link to class)
|
||||
# - @link, @linkplain (doesn't change font)
|
||||
# - @return, @returns
|
||||
# - @see
|
||||
# - @since
|
||||
# - @value (shown as link instead of replacement)
|
||||
# - @version
|
||||
#
|
||||
# Stripped tags:
|
||||
#
|
||||
# - @inheritDoc
|
||||
# - @serial, @serialField, @serialData
|
||||
# - All other block level tags.
|
||||
#
|
||||
# Unsupported tags:
|
||||
#
|
||||
# These will appear literally in the output because I cannot handle them easily.
|
||||
#
|
||||
# - @docRoot
|
||||
# - Any other tags not mentioned
|
||||
#
|
||||
# Supported HTML:
|
||||
#
|
||||
# - p
|
||||
# - b, i, u
|
||||
# - pre
|
||||
# - a href
|
||||
# - ol, ul, li (ol gets converted to ul)
|
||||
# - gt, lt, amp, quot, nbsp entities
|
||||
#
|
||||
# Stripped HTML:
|
||||
#
|
||||
# - code
|
||||
# - HTML comments
|
||||
#
|
||||
# Unsupported HTML:
|
||||
#
|
||||
# These will appear literally in the output because I cannot handle them easily.
|
||||
#
|
||||
# - Any tags with additional properties other than a href. (ex. <p class=Something>)
|
||||
# - Any other tags not mentioned
|
||||
#
|
||||
# Reference:
|
||||
#
|
||||
# http://java.sun.com/j2se/1.5.0/docs/tooldocs/windows/javadoc.html
|
||||
#
|
||||
###############################################################################
|
||||
|
||||
# This file is part of Natural Docs, which is Copyright <20> 2003-2010 Greg Valure
|
||||
# Natural Docs is licensed under version 3 of the GNU Affero General Public License (AGPL)
|
||||
# Refer to License.txt for the complete details
|
||||
|
||||
use strict;
|
||||
use integer;
|
||||
|
||||
package NaturalDocs::Parser::JavaDoc;
|
||||
|
||||
|
||||
#
|
||||
# hash: blockTags
|
||||
# An existence hash of the all-lowercase JavaDoc block tags, not including the @.
|
||||
#
|
||||
my %blockTags = ( 'param' => 1, 'author' => 1, 'deprecated' => 1, 'exception' => 1, 'return' => 1, 'see' => 1,
|
||||
'serial' => 1, 'serialfield' => 1, 'serialdata' => 1, 'since' => 1, 'throws' => 1, 'version' => 1,
|
||||
'returns' => 1 );
|
||||
|
||||
#
|
||||
# hash: inlineTags
|
||||
# An existence hash of the all-lowercase JavaDoc inline tags, not including the @.
|
||||
#
|
||||
my %inlineTags = ( 'inheritdoc' => 1, 'docroot' => 1, 'code' => 1, 'literal' => 1, 'link' => 1, 'linkplain' => 1, 'value' => 1 );
|
||||
|
||||
|
||||
##
|
||||
# Examines the comment and returns whether it is *definitely* JavaDoc content, i.e. is owned by this package.
|
||||
#
|
||||
# Parameters:
|
||||
#
|
||||
# commentLines - An arrayref of the comment lines. Must have been run through <NaturalDocs::Parser->CleanComment()>.
|
||||
# isJavaDoc - Whether the comment is JavaDoc styled. This doesn't necessarily mean it has JavaDoc content.
|
||||
#
|
||||
# Returns:
|
||||
#
|
||||
# Whether the comment is *definitely* JavaDoc content.
|
||||
#
|
||||
sub IsMine #(string[] commentLines, bool isJavaDoc)
|
||||
{
|
||||
my ($self, $commentLines, $isJavaDoc) = @_;
|
||||
|
||||
if (!$isJavaDoc)
|
||||
{ return undef; };
|
||||
|
||||
for (my $line = 0; $line < scalar @$commentLines; $line++)
|
||||
{
|
||||
if ($commentLines->[$line] =~ /^ *@([a-z]+) /i && exists $blockTags{$1} ||
|
||||
$commentLines->[$line] =~ /\{@([a-z]+) /i && exists $inlineTags{$1})
|
||||
{
|
||||
return 1;
|
||||
};
|
||||
};
|
||||
|
||||
return 0;
|
||||
};
|
||||
|
||||
|
||||
##
|
||||
# Parses the JavaDoc-syntax comment and adds it to the parsed topic list.
|
||||
#
|
||||
# Parameters:
|
||||
#
|
||||
# commentLines - An arrayref of the comment lines. Must have been run through <NaturalDocs::Parser->CleanComment()>.
|
||||
# *The original memory will be changed.*
|
||||
# isJavaDoc - Whether the comment is JavaDoc styled. This doesn't necessarily mean it has JavaDoc content.
|
||||
# lineNumber - The line number of the first of the comment lines.
|
||||
# parsedTopics - A reference to the array where any new <NaturalDocs::Parser::ParsedTopics> should be placed.
|
||||
#
|
||||
# Returns:
|
||||
#
|
||||
# The number of parsed topics added to the array, which in this case will always be one.
|
||||
#
|
||||
sub ParseComment #(string[] commentLines, bool isJavaDoc, int lineNumber, ParsedTopics[]* parsedTopics)
|
||||
{
|
||||
my ($self, $commentLines, $isJavaDoc, $lineNumber, $parsedTopics) = @_;
|
||||
|
||||
|
||||
# Stage one: Before block level tags.
|
||||
|
||||
my $i = 0;
|
||||
my $output;
|
||||
my $unformattedText;
|
||||
my $inCode;
|
||||
my $sharedCodeIndent;
|
||||
|
||||
while ($i < scalar @$commentLines &&
|
||||
!($commentLines->[$i] =~ /^ *@([a-z]+) /i && exists $blockTags{$1}) )
|
||||
{
|
||||
my $line = $self->ConvertAmpChars($commentLines->[$i]);
|
||||
my @tokens = split(/(<\/?pre>)/, $line);
|
||||
|
||||
foreach my $token (@tokens)
|
||||
{
|
||||
if ($token =~ /^<pre>$/i)
|
||||
{
|
||||
if (!$inCode && $unformattedText)
|
||||
{
|
||||
$output .= '<p>' . $self->FormatText($unformattedText, 1) . '</p>';
|
||||
};
|
||||
|
||||
$inCode = 1;
|
||||
$unformattedText = undef;
|
||||
}
|
||||
elsif ($token =~ /^<\/pre>$/i)
|
||||
{
|
||||
if ($inCode && $unformattedText)
|
||||
{
|
||||
$unformattedText =~ s/^ {$sharedCodeIndent}//mg;
|
||||
$unformattedText =~ s/\n{3,}/\n\n/g;
|
||||
$unformattedText =~ s/\n+$//;
|
||||
$output .= '<code type="anonymous">' . $unformattedText . '</code>';
|
||||
|
||||
$sharedCodeIndent = undef;
|
||||
};
|
||||
|
||||
$inCode = 0;
|
||||
$unformattedText = undef;
|
||||
}
|
||||
elsif (length($token))
|
||||
{
|
||||
if (!$inCode)
|
||||
{
|
||||
$token =~ s/^ +//;
|
||||
if ($unformattedText)
|
||||
{ $unformattedText .= ' '; };
|
||||
}
|
||||
else
|
||||
{
|
||||
$token =~ /^( *)/;
|
||||
my $indent = length($1);
|
||||
|
||||
if (!defined $sharedCodeIndent || $indent < $sharedCodeIndent)
|
||||
{ $sharedCodeIndent = $indent; };
|
||||
};
|
||||
|
||||
$unformattedText .= $token;
|
||||
};
|
||||
};
|
||||
|
||||
if ($inCode && $unformattedText)
|
||||
{ $unformattedText .= "\n"; };
|
||||
|
||||
$i++;
|
||||
};
|
||||
|
||||
if ($unformattedText)
|
||||
{
|
||||
if ($inCode)
|
||||
{
|
||||
$unformattedText =~ s/^ {$sharedCodeIndent}//mg;
|
||||
$unformattedText =~ s/\n{3,}/\n\n/g;
|
||||
$unformattedText =~ s/\n+$//;
|
||||
$output .= '<code type="anonymous">' . $unformattedText . '</code>';
|
||||
}
|
||||
else
|
||||
{ $output .= '<p>' . $self->FormatText($unformattedText, 1) . '</p>'; };
|
||||
|
||||
$unformattedText = undef;
|
||||
};
|
||||
|
||||
|
||||
# Stage two: Block level tags.
|
||||
|
||||
my ($keyword, $value, $unformattedTextPtr, $unformattedTextCloser);
|
||||
my ($params, $authors, $deprecation, $throws, $returns, $seeAlso, $since, $version);
|
||||
|
||||
|
||||
while ($i < scalar @$commentLines)
|
||||
{
|
||||
my $line = $self->ConvertAmpChars($commentLines->[$i]);
|
||||
$line =~ s/^ +//;
|
||||
|
||||
if ($line =~ /^@([a-z]+) ?(.*)$/i)
|
||||
{
|
||||
($keyword, $value) = (lc($1), $2);
|
||||
|
||||
# Process the previous one, if any.
|
||||
if ($unformattedText)
|
||||
{
|
||||
$$unformattedTextPtr .= $self->FormatText($unformattedText) . $unformattedTextCloser;
|
||||
$unformattedText = undef;
|
||||
};
|
||||
|
||||
if ($keyword eq 'param')
|
||||
{
|
||||
$value =~ /^([a-z0-9_]+) *(.*)$/i;
|
||||
|
||||
$params .= '<de>' . $1 . '</de><dd>';
|
||||
$unformattedText = $2;
|
||||
|
||||
$unformattedTextPtr = \$params;
|
||||
$unformattedTextCloser = '</dd>';
|
||||
}
|
||||
elsif ($keyword eq 'exception' || $keyword eq 'throws')
|
||||
{
|
||||
$value =~ /^([a-z0-9_]+) *(.*)$/i;
|
||||
|
||||
$throws .= '<de>' . $1 . '</de><dd>';
|
||||
$unformattedText = $2;
|
||||
|
||||
$unformattedTextPtr = \$throws;
|
||||
$unformattedTextCloser = '</dd>';
|
||||
}
|
||||
elsif ($keyword eq 'return' || $keyword eq 'returns')
|
||||
{
|
||||
if ($returns)
|
||||
{ $returns .= ' '; };
|
||||
|
||||
$unformattedText = $value;
|
||||
$unformattedTextPtr = \$returns;
|
||||
$unformattedTextCloser = undef;
|
||||
}
|
||||
elsif ($keyword eq 'author')
|
||||
{
|
||||
if ($authors)
|
||||
{ $authors .= ', '; };
|
||||
|
||||
$unformattedText = $value;
|
||||
$unformattedTextPtr = \$authors;
|
||||
$unformattedTextCloser = undef;
|
||||
}
|
||||
elsif ($keyword eq 'deprecated')
|
||||
{
|
||||
if ($deprecation)
|
||||
{ $deprecation .= ' '; };
|
||||
|
||||
$unformattedText = $value;
|
||||
$unformattedTextPtr = \$deprecation;
|
||||
$unformattedTextCloser = undef;
|
||||
}
|
||||
elsif ($keyword eq 'since')
|
||||
{
|
||||
if ($since)
|
||||
{ $since .= ', '; };
|
||||
|
||||
$unformattedText = $value;
|
||||
$unformattedTextPtr = \$since;
|
||||
$unformattedTextCloser = undef;
|
||||
}
|
||||
elsif ($keyword eq 'version')
|
||||
{
|
||||
if ($version)
|
||||
{ $version .= ', '; };
|
||||
|
||||
$unformattedText = $value;
|
||||
$unformattedTextPtr = \$version;
|
||||
$unformattedTextCloser = undef;
|
||||
}
|
||||
elsif ($keyword eq 'see')
|
||||
{
|
||||
if ($seeAlso)
|
||||
{ $seeAlso .= ', '; };
|
||||
|
||||
$unformattedText = undef;
|
||||
|
||||
if ($value =~ /^&(?:quot|lt);/i)
|
||||
{ $seeAlso .= $self->FormatText($value); }
|
||||
else
|
||||
{ $seeAlso .= $self->ConvertLink($value); };
|
||||
};
|
||||
|
||||
# Everything else will be skipped.
|
||||
}
|
||||
elsif ($unformattedText)
|
||||
{
|
||||
$unformattedText .= ' ' . $line;
|
||||
};
|
||||
|
||||
$i++;
|
||||
};
|
||||
|
||||
if ($unformattedText)
|
||||
{
|
||||
$$unformattedTextPtr .= $self->FormatText($unformattedText) . $unformattedTextCloser;
|
||||
$unformattedText = undef;
|
||||
};
|
||||
|
||||
if ($params)
|
||||
{ $output .= '<h>Parameters</h><dl>' . $params . '</dl>'; };
|
||||
if ($returns)
|
||||
{ $output .= '<h>Returns</h><p>' . $returns . '</p>'; };
|
||||
if ($throws)
|
||||
{ $output .= '<h>Throws</h><dl>' . $throws . '</dl>'; };
|
||||
if ($since)
|
||||
{ $output .= '<h>Since</h><p>' . $since . '</p>'; };
|
||||
if ($version)
|
||||
{ $output .= '<h>Version</h><p>' . $version . '</p>'; };
|
||||
if ($deprecation)
|
||||
{ $output .= '<h>Deprecated</h><p>' . $deprecation . '</p>'; };
|
||||
if ($authors)
|
||||
{ $output .= '<h>Author</h><p>' . $authors . '</p>'; };
|
||||
if ($seeAlso)
|
||||
{ $output .= '<h>See Also</h><p>' . $seeAlso . '</p>'; };
|
||||
|
||||
|
||||
# Stage three: Build the parsed topic.
|
||||
|
||||
my $summary = NaturalDocs::Parser->GetSummaryFromBody($output);
|
||||
|
||||
push @$parsedTopics, NaturalDocs::Parser::ParsedTopic->New(undef, undef, undef, undef, undef, $summary,
|
||||
$output, $lineNumber, undef);
|
||||
return 1;
|
||||
};
|
||||
|
||||
|
||||
##
|
||||
# Translates any inline tags or HTML codes to <NDMarkup> and returns it.
|
||||
#
|
||||
sub FormatText #(string text, bool inParagraph)
|
||||
{
|
||||
my ($self, $text, $inParagraph) = @_;
|
||||
|
||||
# JavaDoc Literal
|
||||
|
||||
$text =~ s/\{\@(?:code|literal) ([^\}]*)\}/$self->ConvertAmpChars($1)/gie;
|
||||
|
||||
|
||||
# HTML
|
||||
|
||||
$text =~ s/<b>(.*?)<\/b>/<b>$1<\/b>/gi;
|
||||
$text =~ s/<i>(.*?)<\/i>/<i>$1<\/i>/gi;
|
||||
$text =~ s/<u>(.*?)<\/u>/<u>$1<\/u>/gi;
|
||||
|
||||
$text =~ s/<code>(.*?)<\/code>/$1/gi;
|
||||
|
||||
$text =~ s/<ul.*?>(.*?)<\/ul>/<ul>$1<\/ul>/gi;
|
||||
$text =~ s/<ol.*?>(.*?)<\/ol>/<ul>$1<\/ul>/gi;
|
||||
$text =~ s/<li.*?>(.*?)<\/li>/<li>$1<\/li>/gi;
|
||||
|
||||
$text =~ s/<!--.*?-->//gi;
|
||||
|
||||
$text =~ s/<\/p>//gi;
|
||||
$text =~ s/^<p>//i;
|
||||
if ($inParagraph)
|
||||
{ $text =~ s/<p>/<\/p><p>/gi; }
|
||||
else
|
||||
{ $text =~ s/<p>//gi; };
|
||||
|
||||
$text =~ s/<a href="mailto:(.*?)".*?>(.*?)<\/a>/$self->MakeEMailLink($1, $2)/gie;
|
||||
$text =~ s/<a href="(.*?)".*?>(.*?)<\/a>/$self->MakeURLLink($1, $2)/gie;
|
||||
|
||||
$text =~ s/&nbsp;/ /gi;
|
||||
$text =~ s/&amp;/&/gi;
|
||||
$text =~ s/&gt;/>/gi;
|
||||
$text =~ s/&lt;/</gi;
|
||||
$text =~ s/&quot;/"/gi;
|
||||
|
||||
|
||||
|
||||
# JavaDoc
|
||||
|
||||
$text =~ s/\{\@inheritdoc\}//gi;
|
||||
$text =~ s/\{\@(?:linkplain|link|value) ([^\}]*)\}/$self->ConvertLink($1)/gie;
|
||||
|
||||
return $text;
|
||||
};
|
||||
|
||||
|
||||
sub ConvertAmpChars #(text)
|
||||
{
|
||||
my ($self, $text) = @_;
|
||||
|
||||
$text =~ s/&/&/g;
|
||||
$text =~ s/</</g;
|
||||
$text =~ s/>/>/g;
|
||||
$text =~ s/"/"/g;
|
||||
|
||||
return $text;
|
||||
};
|
||||
|
||||
sub ConvertLink #(text)
|
||||
{
|
||||
my ($self, $text) = @_;
|
||||
|
||||
$text =~ /^ *([a-z0-9\_\.\:\#]+(?:\([^\)]*\))?) *(.*)$/i;
|
||||
my ($target, $label) = ($1, $2);
|
||||
|
||||
# Convert the anchor to part of the link, but remove it altogether if it's the beginning of the link.
|
||||
$target =~ s/^\#//;
|
||||
$target =~ s/\#/\./;
|
||||
|
||||
$label =~ s/ +$//;
|
||||
|
||||
if (!length $label)
|
||||
{ return '<link target="' . $target . '" name="' . $target . '" original="' . $target . '">'; }
|
||||
else
|
||||
{ return '<link target="' . $target . '" name="' . $label . '" original="' . $label . ' (' . $target . ')">'; };
|
||||
};
|
||||
|
||||
sub MakeURLLink #(target, text)
|
||||
{
|
||||
my ($self, $target, $text) = @_;
|
||||
return '<url target="' . $target . '" name="' . $text . '">';
|
||||
};
|
||||
|
||||
sub MakeEMailLink #(target, text)
|
||||
{
|
||||
my ($self, $target, $text) = @_;
|
||||
return '<email target="' . $target . '" name="' . $text . '">';
|
||||
};
|
||||
|
||||
|
||||
1;
|
||||
1073
lib/ann/fann/docs/NaturalDocs-1.52/Modules/NaturalDocs/Parser/Native.pm
Executable file
1073
lib/ann/fann/docs/NaturalDocs-1.52/Modules/NaturalDocs/Parser/Native.pm
Executable file
File diff suppressed because it is too large
Load Diff
254
lib/ann/fann/docs/NaturalDocs-1.52/Modules/NaturalDocs/Parser/ParsedTopic.pm
Executable file
254
lib/ann/fann/docs/NaturalDocs-1.52/Modules/NaturalDocs/Parser/ParsedTopic.pm
Executable file
@ -0,0 +1,254 @@
|
||||
###############################################################################
|
||||
#
|
||||
# Package: NaturalDocs::Parser::ParsedTopic
|
||||
#
|
||||
###############################################################################
|
||||
#
|
||||
# A class for parsed topics of source files. Also encompasses some of the <TopicType>-specific behavior.
|
||||
#
|
||||
###############################################################################
|
||||
|
||||
# This file is part of Natural Docs, which is Copyright <20> 2003-2010 Greg Valure
|
||||
# Natural Docs is licensed under version 3 of the GNU Affero General Public License (AGPL)
|
||||
# Refer to License.txt for the complete details
|
||||
|
||||
use strict;
|
||||
use integer;
|
||||
|
||||
package NaturalDocs::Parser::ParsedTopic;
|
||||
|
||||
|
||||
###############################################################################
|
||||
# Group: Implementation
|
||||
|
||||
#
|
||||
# Constants: Members
|
||||
#
|
||||
# The object is a blessed arrayref with the following indexes.
|
||||
#
|
||||
# TYPE - The <TopicType>.
|
||||
# TITLE - The title of the topic.
|
||||
# PACKAGE - The package <SymbolString> the topic appears in, or undef if none.
|
||||
# USING - An arrayref of additional package <SymbolStrings> available to the topic via "using" statements, or undef if
|
||||
# none.
|
||||
# PROTOTYPE - The prototype, if it exists and is applicable.
|
||||
# SUMMARY - The summary, if it exists.
|
||||
# BODY - The body of the topic, formatted in <NDMarkup>. Some topics may not have bodies, and if not, this
|
||||
# will be undef.
|
||||
# LINE_NUMBER - The line number the topic appears at in the file.
|
||||
# IS_LIST - Whether the topic is a list.
|
||||
#
|
||||
use NaturalDocs::DefineMembers 'TYPE', 'TITLE', 'PACKAGE', 'USING', 'PROTOTYPE', 'SUMMARY', 'BODY',
|
||||
'LINE_NUMBER', 'IS_LIST';
|
||||
# DEPENDENCY: New() depends on the order of these constants, and that this class is not inheriting any members.
|
||||
|
||||
|
||||
#
|
||||
# Architecture: Title, Package, and Symbol Behavior
|
||||
#
|
||||
# Title, package, and symbol behavior is a little awkward so it deserves some explanation. Basically you set them according to
|
||||
# certain rules, but you get computed values that try to hide all the different scoping situations.
|
||||
#
|
||||
# Normal Topics:
|
||||
#
|
||||
# Set them to the title and package as they appear. "Function" and "PkgA.PkgB" will return "Function" for the title,
|
||||
# "PkgA.PkgB" for the package, and "PkgA.PkgB.Function" for the symbol.
|
||||
#
|
||||
# In the rare case that a title has a separator symbol it's treated as inadvertant, so "A vs. B" in "PkgA.PkgB" still returns just
|
||||
# "PkgA.PkgB" for the package even though if you got it from the symbol it can be seen as "PkgA.PkgB.A vs".
|
||||
#
|
||||
# Scope Topics:
|
||||
#
|
||||
# Set the title normally and leave the package undef. So "PkgA.PkgB" and undef will return "PkgA.PkgB" for the title as well
|
||||
# as for the package and symbol.
|
||||
#
|
||||
# The only time you should set the package is when you have full language support and they only documented the class with
|
||||
# a partial title. So if you documented "PkgA.PkgB" with just "PkgB", you want to set the package to "PkgA". This
|
||||
# will return "PkgB" as the title for presentation and will return "PkgA.PkgB" for the package and symbol, which is correct.
|
||||
#
|
||||
# Always Global Topics:
|
||||
#
|
||||
# Set the title and package normally, do not set the package to undef. So "Global" and "PkgA.PkgB" will return "Global" as
|
||||
# the title, "PkgA.PkgB" as the package, and "Global" as the symbol.
|
||||
#
|
||||
# Um, yeah...:
|
||||
#
|
||||
# So does this suck? Yes, yes it does. But the suckiness is centralized here instead of having to be handled everywhere these
|
||||
# issues come into play. Just realize there are a certain set of rules to follow when you *set* these variables, and the results
|
||||
# you see when you *get* them are computed rather than literal.
|
||||
#
|
||||
|
||||
|
||||
###############################################################################
|
||||
# Group: Functions
|
||||
|
||||
#
|
||||
# Function: New
|
||||
#
|
||||
# Creates a new object.
|
||||
#
|
||||
# Parameters:
|
||||
#
|
||||
# type - The <TopicType>.
|
||||
# title - The title of the topic.
|
||||
# package - The package <SymbolString> the topic appears in, or undef if none.
|
||||
# using - An arrayref of additional package <SymbolStrings> available to the topic via "using" statements, or undef if
|
||||
# none.
|
||||
# prototype - The prototype, if it exists and is applicable. Otherwise set to undef.
|
||||
# summary - The summary of the topic, if any.
|
||||
# body - The body of the topic, formatted in <NDMarkup>. May be undef, as some topics may not have bodies.
|
||||
# lineNumber - The line number the topic appears at in the file.
|
||||
# isList - Whether the topic is a list topic or not.
|
||||
#
|
||||
# Returns:
|
||||
#
|
||||
# The new object.
|
||||
#
|
||||
sub New #(type, title, package, using, prototype, summary, body, lineNumber, isList)
|
||||
{
|
||||
# DEPENDENCY: This depends on the order of the parameter list being the same as the constants, and that there are no
|
||||
# members inherited from a base class.
|
||||
|
||||
my $package = shift;
|
||||
|
||||
my $object = [ @_ ];
|
||||
bless $object, $package;
|
||||
|
||||
if (defined $object->[USING])
|
||||
{ $object->[USING] = [ @{$object->[USING]} ]; };
|
||||
|
||||
return $object;
|
||||
};
|
||||
|
||||
|
||||
# Function: Type
|
||||
# Returns the <TopicType>.
|
||||
sub Type
|
||||
{ return $_[0]->[TYPE]; };
|
||||
|
||||
# Function: SetType
|
||||
# Replaces the <TopicType>.
|
||||
sub SetType #(type)
|
||||
{ $_[0]->[TYPE] = $_[1]; };
|
||||
|
||||
# Function: IsList
|
||||
# Returns whether the topic is a list.
|
||||
sub IsList
|
||||
{ return $_[0]->[IS_LIST]; };
|
||||
|
||||
# Function: SetIsList
|
||||
# Sets whether the topic is a list.
|
||||
sub SetIsList
|
||||
{ $_[0]->[IS_LIST] = $_[1]; };
|
||||
|
||||
# Function: Title
|
||||
# Returns the title of the topic.
|
||||
sub Title
|
||||
{ return $_[0]->[TITLE]; };
|
||||
|
||||
# Function: SetTitle
|
||||
# Replaces the topic title.
|
||||
sub SetTitle #(title)
|
||||
{ $_[0]->[TITLE] = $_[1]; };
|
||||
|
||||
#
|
||||
# Function: Symbol
|
||||
#
|
||||
# Returns the <SymbolString> defined by the topic. It is fully resolved and does _not_ need to be joined with <Package()>.
|
||||
#
|
||||
# Type-Specific Behavior:
|
||||
#
|
||||
# - If the <TopicType> is always global, the symbol will be generated from the title only.
|
||||
# - Everything else's symbols will be generated from the title and the package passed to <New()>.
|
||||
#
|
||||
sub Symbol
|
||||
{
|
||||
my ($self) = @_;
|
||||
|
||||
my $titleSymbol = NaturalDocs::SymbolString->FromText($self->[TITLE]);
|
||||
|
||||
if (NaturalDocs::Topics->TypeInfo($self->Type())->Scope() == ::SCOPE_ALWAYS_GLOBAL())
|
||||
{ return $titleSymbol; }
|
||||
else
|
||||
{
|
||||
return NaturalDocs::SymbolString->Join( $self->[PACKAGE], $titleSymbol );
|
||||
};
|
||||
};
|
||||
|
||||
|
||||
#
|
||||
# Function: Package
|
||||
#
|
||||
# Returns the package <SymbolString> that the topic appears in.
|
||||
#
|
||||
# Type-Specific Behavior:
|
||||
#
|
||||
# - If the <TopicType> has scope, the package will be generated from both the title and the package passed to <New()>, not
|
||||
# just the package.
|
||||
# - If the <TopicType> is always global, the package will be the one passed to <New()>, even though it isn't part of it's
|
||||
# <Symbol()>.
|
||||
# - Everything else's package will be what was passed to <New()>, even if the title has separator symbols in it.
|
||||
#
|
||||
sub Package
|
||||
{
|
||||
my ($self) = @_;
|
||||
|
||||
# Headerless topics may not have a type yet.
|
||||
if ($self->Type() && NaturalDocs::Topics->TypeInfo($self->Type())->Scope() == ::SCOPE_START())
|
||||
{ return $self->Symbol(); }
|
||||
else
|
||||
{ return $self->[PACKAGE]; };
|
||||
};
|
||||
|
||||
|
||||
# Function: SetPackage
|
||||
# Replaces the package the topic appears in. This will behave the same way as the package parameter in <New()>. Later calls
|
||||
# to <Package()> will still be generated according to its type-specific behavior.
|
||||
sub SetPackage #(package)
|
||||
{ $_[0]->[PACKAGE] = $_[1]; };
|
||||
|
||||
# Function: Using
|
||||
# Returns an arrayref of additional scope <SymbolStrings> available to the topic via "using" statements, or undef if none.
|
||||
sub Using
|
||||
{ return $_[0]->[USING]; };
|
||||
|
||||
# Function: SetUsing
|
||||
# Replaces the using arrayref of sope <SymbolStrings>.
|
||||
sub SetUsing #(using)
|
||||
{ $_[0]->[USING] = $_[1]; };
|
||||
|
||||
# Function: Prototype
|
||||
# Returns the prototype if one is defined. Will be undef otherwise.
|
||||
sub Prototype
|
||||
{ return $_[0]->[PROTOTYPE]; };
|
||||
|
||||
# Function: SetPrototype
|
||||
# Replaces the function or variable prototype.
|
||||
sub SetPrototype #(prototype)
|
||||
{ $_[0]->[PROTOTYPE] = $_[1]; };
|
||||
|
||||
# Function: Summary
|
||||
# Returns the topic summary, if it exists, formatted in <NDMarkup>.
|
||||
sub Summary
|
||||
{ return $_[0]->[SUMMARY]; };
|
||||
|
||||
# Function: Body
|
||||
# Returns the topic's body, formatted in <NDMarkup>. May be undef.
|
||||
sub Body
|
||||
{ return $_[0]->[BODY]; };
|
||||
|
||||
# Function: SetBody
|
||||
# Replaces the topic's body, formatted in <NDMarkup>. May be undef.
|
||||
sub SetBody #(body)
|
||||
{
|
||||
my ($self, $body) = @_;
|
||||
$self->[BODY] = $body;
|
||||
};
|
||||
|
||||
# Function: LineNumber
|
||||
# Returns the line the topic appears at in the file.
|
||||
sub LineNumber
|
||||
{ return $_[0]->[LINE_NUMBER]; };
|
||||
|
||||
|
||||
1;
|
||||
Reference in New Issue
Block a user